评分

已解决将覆盖率与道路和边界距离联系起来的规则

1个月前更新

211

您好，
根据标题，我正在尝试创建一条规则，将地块的覆盖率与道路和边界的距离联系起来。首先，我要说我是 cityengine 的新手。
我已经研究这条规则两周了，阅读了几篇文章，关注了几个 youtube 视频。我设法创建了一条规则，将 notto 分为 5 个部分。
建筑物突出的中央部分和另外 4 个自由部分。我将地块分成所有这些部分，以便我可以调整到边界和道路的距离并控制建筑物表面。
只是有一个问题。控制并不完美，事实上，为了能够改变距离，我必须对不同地块的面积百分比采取行动。这很不方便，因为它不允许我直接对距离采取行动。
作为初学者，我想知道是否有办法实现这个结果。
提前致谢

评分

欢迎为Ta评分

回答1

只看作者

最新最热

UrbanEngine

超级版主0

例如，您可以先使用计算边缘属性工具获取地块形状的方向。然后，以下规则允许您定义最大建筑物覆盖率和每侧的后退距离。如果最大覆盖率小于setbackPerEdge操作的其余部分，则前部后退将通过setbackToArea操作增加（深蓝色区域）。托马斯福克斯_1-1741250823630.png


version "2024.1"

const lotArea = geometry.area
@Description("Maximum ratio of footprint to parcel area") @Percent 
attr area_ratio = 0.5 
@Description("Minimum street setback") @Distance @Range(min=0, max=15) 
attr setback_front = 5
@Description("Excact side setback") @Distance @Range(min=0, max=15) 
attr setback_side = 10
@Description("Excact rear setback") @Distance @Range(min=0, max=15) 
attr setback_rear = 15

dist(orientation) = case orientation == "front"	: setback_front
                    case orientation == "side"	: setback_side
                    case orientation == "rear"	: setback_rear
                    else                   	 	: 0

@StartRule
SetbackPerEdge --> setbackPerEdge( dist( edgeAttr.getString("orientations") ) ) 
	{ edgeAttr.getString("orientations") == "front"	= Grey
	| edgeAttr.getString("orientations") == "side" 	= Yellow
	| edgeAttr.getString("orientations") == "rear"	= Green
	| remainder 	= SetbackToArea }

SetbackToArea --> setbackToArea(lotArea * area_ratio) 
	{ edgeAttr.getString("orientations") == "front"	= Blue 
	| remainder = extrude(10) Cyan }

1个月前回复已采纳