基于规则的建模

CityEngine 是一种“程序化建模应用”，意味着二维形状通过一系列程序（CGA 规则文件）转换成一个3D模型。 CityEngine 的力量在于CGA（计算机生成建筑）。 CityEngine 的CGA是唯一一种可以指定来生成建筑3D内容的编程语言。本质上，当CGA规则被分配或应用于形状时，就会创建3D模型。3D模型的复杂性取决于CGA规则及其内部指令。一个简单的CGA文件可能会将建筑足迹形状拉伸以赋予其3D形式或质量。而更复杂的CGA规则可能会在质量的外墙上应用纹理，或者将其分割成其他部分，生成丰富、详细的3D模型。

编写CGA的关键之一是逐步编写规则并在过程中逐步添加功能。虽然制定期望结果的计划很重要，但你不能编写500行代码然后点击开始。相反，你应该逐步构建规则，并在过程中测试结果。

本教程将指导您创建一条规则，从一个简单的平面图生成一系列3D建筑。

打开场景

首先，打开项目中的BasicsOfRules.cej 场景 场景文件夹：

你好，世界！

在编程中有一个东西叫做“Hello, World!”——一种编写简单代码以输出简单消息的方法，这样你就可以看到基本语法并确认你的代码是否正常工作。在CityEngine中，一个简单的“Hello World!”版本是一个对随机高度进行简单挤压并为形状应用颜色的示例。

所以要创建你的第一个规则，右键点击 \rules\ 文件夹，然后前往 新建 > CGA 规则文件 并将规则命名为 DetailedBuilding.cga.

首先，在声明CityEngine版本的代码行下面添加以下几行，例如版本 20XX.X，然后保存您的规则。

@StartRule
Footprint -->
	extrude(rand(10,100))  
	color(1,1,0)

通过注释@StartRule，这使得Footprint规则可以从选择器中使用。下一行将形状随机拉伸到10到100米的高度。最后，最后一行在RGB中将形状着成黄色。

分配规则

保存规则后，选择图形并分配规则，可以通过直接将CGA规则文件从导航器窗口拖放到选定的图形上，点击 分配 在规则部分的检查器窗口中，或者点击主菜单中的图形>分配规则文件。如果分配了新规则后没有发生任何变化，请点击 生成模型工具  (Ctrl+G) 或点击主菜单中的图形>生成模型。

添加属性

既然你的规则已经生效，将高度作为一个属性添加到规则中，以增加规则的额外功能。请记住，关键在于逐步更改，所以你不是从头开始，而是要修改你已经创建的规则：

@Group("Building Shell")
@Range(min=0, max=100, stepsize=1)
attr building_height = rint(rand(10,100))

@StartRule
Footprint -->
	extrude(building_height)  
	color(1,1,0)

这些更改将随机建筑高度移动到一个名为building_height的属性。这仍然为每个形状生成，但将其移动到您可以在 Inspector窗口中控制的属性。您还添加了一个新的内置函数rint，该函数将随机数四舍五入到最接近的整数。

该@Group注释帮助你组织属性在检查器窗口中的显示位置。该@Range注释控制滑块的功能。通过将建筑高度设置为属性，你现在有一个滑块来控制每个形状的高度。

现在，如果你点击一个建筑，你可以调整高度并覆盖随机数。此外，滑块现在只在0到100之间，即你范围的最小值和最大值。

添加手柄

手柄扩展了你的属性功能，并以一种非常直观和互动的方式将控制带入场景。

添加@Handle 注释和Mass 规则，以包括控制模型中建筑物高度的把手：

@Group("Building Shell")
@Handle(shape=Mass, axis=y)
@Range(min=0, max=100, stepsize=1)
attr building_height = rint(rand(0,100))

@StartRule
Footprint -->
	extrude(building_height)  
	color(1,1,0)
	Mass

记得重新生成你的模型 (CTRL+G) – 建筑物上会出现把手，允许你调整高度属性。

添加楼层拆分

继续对你的规则进行增量修改，现在你将添加一些代码，以在每层楼沿着y轴垂直分割建筑物。

创建 质量 规则，并使用由新 floor_height 属性控制的拆分操作。请注意，默认单位是米，因此下面的代码显示3.048米，注释 # 只是告诉你这是10英尺。

@Group("Building Shell")
@Handle(shape=Mass, axis=y)
@Range(min=0, max=100, stepsize=1)
attr building_height = rint(rand(10,100))

@Range(min=1, max=25, stepsize=1)
attr floor_height = 3.048	# 10 feet


@StartRule
Footprint -->
	extrude(building_height)  
	color(1,1,0)
	Mass

Mass -->
	split(y) { floor_height : Floor }*

你可能会注意到大楼的顶层楼高不同。这是因为分隔从底层开始并向上进行，顶层的楼高是所有分隔完成后剩下的高度。

解决这个问题的一种方法是在楼高前面添加一个波浪号（~）。这告诉CityEngine使用浮动大小，使软件能够自动调整分裂。每层楼的高度不会正好是3.048米，但它们会全部相等，并且不会有剩余部分。

Mass -->
	split(y) { ~floor_height : Floor }*

构建一个用于使用的着色函数

首先，您应该注释掉您在@StartRule中分配颜色到脚印的那行代码。尽管在规则之间处理形状时您可以多次更改颜色，但只设置一次颜色是良好的编程习惯。

添加 #color(1,1,0) 注释：

@StartRule
Footprint -->
	extrude(building_height)  
	#color(1,1,0)
	Mass

函数是一段可以执行特定过程并返回值的代码块或程序。要根据土地利用情况为你的楼层上色，你可以创建一个简单的函数，该函数可以被调用来使用适当的颜色。为此，你还需要创建属性，以便根据楼层位置选择不同的土地利用类型。

@Group("Building Shell")
@Handle(shape=Mass, axis=y)
@Range(min=0, max=100, stepsize=1)
attr building_height = rint(rand(10,100))
@Range(min=1, max=25, stepsize=1)
attr floor_height = 3.048	# 10 feet

@Group("Land Use")
@Enum("Retail","Office","Multi-Family")
attr use_ground = "Retail"

@Enum("Retail","Office","Multi-Family")
attr use_upper = "Multi-Family"

接下来，在你的属性和@StartRule之间创建一个新的函数。下面的函数接收use参数并评估它以返回外墙的正确颜色。如果use参数不匹配，它会传递颜色 #FFFFFF，即白色。

getColor(use) = 		case use == "Retail" : "#FF6633"
				case use == "Office" : "#6699FF"
				case use == "Multi-Family" : "#A97C50" 
				else: "#FFFFFF"

最后，通过找到底层和上层楼层，然后调用函数为楼层着色，将所有内容组合在一起。为了将顶层与所有上层楼层的分割区分开来，你使用 split.index 和 split.total，这些在你调用分割函数时会被创建。为此，你需要扩展你的代码，添加 Floor 规则。 Floor 规则首先执行一个条件规则 – case。如果 split.index 为 0，则是底层，否则是上层楼层。一旦楼层确定，函数就会被调用并设置楼层颜色。

Floor -->
	case split.index == 0: 
		color(getColor(use_ground))
	else:
		color(getColor(use_upper))

通过调整高度和土地利用属性，你现在可以实现更多样化的拓扑结构：

创建一个常量

const unitScale = 0.3048			# convert meters to feet
const areaScale = 10.7639			# convert square meters to square feet
const acres = 43560 			# there are 43,560 square feet in an acre

Floor -->
	case split.index == 0: 
		color(getColor(use_ground))
		Plate
	else:
		color(getColor(use_upper))
		Plate

Plate -->
	comp(f) { side : Wall | bottom : Reporting | top : Top }

Reporting -->
	report("FloorArea", geometry.area)

Reporting -->
	report("FloorArea", geometry.area * areaScale)

Floor -->
	case split.index == 0: 
		color(getColor(use_ground))
		Plate (use_ground)
	else:
		color(getColor(use_upper))
		Plate (use_upper)

Plate(landUse) -->
	comp(f) { side : Wall | bottom : Reporting(landUse) | top : Top }

Reporting(landUse) -->
	report("FloorArea." + landUse, geometry.area * areaScale)

@StartRule
Footprint -->
	report("LotArea", geometry.area * areaScale)
	extrude(building_height)  
	#color(1,1,0)
	Mass

Reporting(landUse) -->
	report("FloorArea." + landUse, geometry.area * areaScale)
	report("FloorArea." + landUse + "#color", getColor(landUse))